doxygen 소스코드 문서화 스크립트

■다운로드
doxygen: https://www.doxygen.nl/download.html
graphviz: https://graphviz.org/download/

run_doxygen.bat

@ECHO OFF
CHCP 65001

REM ================================
REM 사용자 설정 영역
REM ================================

REM Doxygen 설정 파일 이름
SET DOXYFILE=Doxyfile

REM Graphviz dot.exe 경로 (PATH에 있으면 비워도 됨)
SET DOT_PATH=

REM ================================
REM main
REM ================================

SET "PROJECT_NAME=My Project1"
SET "SOURCE_DIR=c:\@Administrator\0_tmp\src\test1"
SET "OUTPUT_DIR=c:\@Administrator\0_tmp\test1_docs"
CALL :FUNC_MAKE_CONFIG
CALL :FUNC_RUN_DOXYGEN

SET "PROJECT_NAME=My Project2"
SET "OUTPUT_DIR=c:\@Administrator\0_tmp\test2_docs"
SET "SOURCE_DIR=c:\@Administrator\0_tmp\src\test2"
CALL :FUNC_MAKE_CONFIG
CALL :FUNC_RUN_DOXYGEN

PAUSE
EXIT /B

REM ================================
REM Doxyfile 설정 덮어쓰기
REM ================================
:FUNC_MAKE_CONFIG
  IF EXIST %DOXYFILE% DEL /Q %DOXYFILE%
  (
  ECHO PROJECT_NAME           = "%PROJECT_NAME%"
  ECHO OUTPUT_DIRECTORY       = "%OUTPUT_DIR%"
  ECHO INPUT                  = "%SOURCE_DIR%"
  ECHO FILE_PATTERNS          = *.c *.cpp *.h *.hpp
  ECHO RECURSIVE              = YES
  ECHO EXTRACT_ALL            = YES
  ECHO EXTRACT_PRIVATE        = YES
  ECHO EXTRACT_STATIC         = YES
  ECHO GENERATE_HTML          = YES
  ECHO GENERATE_LATEX         = NO
  ECHO HAVE_DOT               = YES
  ECHO DOT_PATH               = "%DOT_PATH%"
  ECHO CLASS_DIAGRAMS         = YES
  ECHO UML_LOOK               = YES
  ECHO CALL_GRAPH             = YES
  ECHO CALLER_GRAPH           = YES
  ECHO COLLABORATION_GRAPH    = YES
  ECHO INCLUDE_GRAPH          = YES
  ECHO INCLUDED_BY_GRAPH      = YES
  ECHO GRAPHICAL_HIERARCHY    = YES
  ECHO DIRECTORY_GRAPH        = YES
  ECHO DOT_IMAGE_FORMAT       = svg
  ECHO INTERACTIVE_SVG        = YES
  ECHO QUIET                  = NO
  ) >> %DOXYFILE%
  GOTO :EOF

REM ================================
REM 문서 생성
REM ================================
:FUNC_RUN_DOXYGEN
  doxygen %DOXYFILE%
  ECHO.
  ECHO ================================
  ECHO Doxygen 문서 생성 완료!
  ECHO 출력 위치: %OUTPUT_DIR%\html\index.html
  ECHO ================================
  GOTO :EOF