@ECHO OFF
CALL :FUNC_CREATE_SHORTCUT "D:\DESKTOP\MYSHORTCUT.LNK" "C:\PORTABLEAPPS\CCLEANER_PORTABLE\CCLEANER64.EXE" "-" "-" 1 "-"
EXIT /B 0
REM -----------------------------------------------------------
REM 바로가기를 만든다.
REM
REM CALL :FUNC_CREATE_SHORTCUT <인수>
REM 인수 %1: 바로가기 파일명
REM %2: 타겟 파일명
REM %3: Arguments or "-"
REM %4: 아이콘 파일명 or "-"
REM %5: 윈도우 스타일 or "-"
REM %6: 시작 디렉토리 or "-"
REM -----------------------------------------------------------
:FUNC_CREATE_SHORTCUT
SET TMP_SCRIPT="%TEMP%\%RANDOM%-%RANDOM%-%RANDOM%-%RANDOM%.vbs"
ECHO Set oWS = WScript.CreateObject("WScript.Shell") > %TMP_SCRIPT%
IF "%1" NEQ "" (
ECHO sLinkFile = %1 >> %TMP_SCRIPT%
)
ECHO Set oLink = oWS.CreateShortcut(sLinkFile) >> %TMP_SCRIPT%
IF "%2" NEQ "" (
ECHO oLink.TargetPath = %2 >> %TMP_SCRIPT%
)
IF %3 NEQ "-" (
ECHO oLink.Arguments = %3 >> %TMP_SCRIPT%
)
IF %4 NEQ "-" (
ECHO oLink.IconLocation = %4 >> %TMP_SCRIPT%
)
REM 1: Default, 3:Maximized Window, 7:Minimized Window
IF %5 NEQ "-" (
ECHO oLink.WindowStyle = %5 >> %TMP_SCRIPT%
)
IF %6 NEQ "-" (
ECHO oLink.WorkingDirectory = %6 >> %TMP_SCRIPT%
)
ECHO oLink.Save >> %TMP_SCRIPT%
CSCRIPT /NOLOGO %TMP_SCRIPT%
DEL /F /Q %TMP_SCRIPT%
EXIT /B 0
