1. 아래 배치를 실행하여 하드디스크의 파티셔닝을 초기화 한다.
@ECHO OFF
REM *****************************************************************
REM DISKPART로 UEFI 파티션을 잡는다.
REM
REM 실행 전 주의사항:
REM DISKPART 실행 후 LIST DISK 커맨드로 0번 디스크가 설치하려는
REM 타겟 디스크인지 반드시 확인한다.
REM *****************************************************************
SET PAR_EFI_SIZE=100
SET PAR_MSR_SIZE=16
SET PAR_C_DRIVE_SIZE=49152
SET PAR_D_DRIVE_SIZE=0
REM *****************************************************************
REM 작업할 디스크 확인
REM *****************************************************************
ECHO LIST DISK > UEFI_PAR.TXT
DISKPART /S UEFI_PAR.TXT
DEL /Q /F UEFI_PAR.TXT
ECHO.
ECHO DISK LIST 입니다. 0번 디스크에 작업할 것입니다. 0번이 대상 디스크가 맞습니까 ?
SET /P YN=(y/n)?
IF /I "%YN%" == "y" GOTO RUN_DISKPART
EXIT /B
:RUN_DISKPART
REM *****************************************************************
REM 디스크를 초기화하고 GPT로 변환한다.
REM *****************************************************************
ECHO SELECT DISK 0 > UEFI_PAR.TXT
ECHO CLEAN >> UEFI_PAR.TXT
ECHO CONVERT GPT >> UEFI_PAR.TXT
REM *****************************************************************
REM EFI 파티션을 생성하고 S:드라이브로 만든다.
REM *****************************************************************
ECHO CREATE PARTITION EFI SIZE=%PAR_EFI_SIZE% >> UEFI_PAR.TXT
ECHO SET ID=C12A7328-F81F-11D2-BA4B-00A0C93EC93B >> UEFI_PAR.TXT
ECHO FORMAT FS=FAT32 QUICK LABEL=EFI >> UEFI_PAR.TXT
ECHO ASSIGN LETTER=S >> UEFI_PAR.TXT
REM *****************************************************************
REM 시스템 예약 파티션 생성 (윈도우7:128MB, 윈도우10:16MB)
REM *****************************************************************
ECHO CREATE PARTITION MSR SIZE=%PAR_MSR_SIZE% >> UEFI_PAR.TXT
REM *****************************************************************
REM SYSTEM 파티션을 생성하고 포맷 후 W:드라이브로 만든다.
REM *****************************************************************
ECHO CREATE PARTITION PRIMARY SIZE=%PAR_C_DRIVE_SIZE% >> UEFI_PAR.TXT
ECHO FORMAT FS=NTFS QUICK LABEL=SYSTEM >> UEFI_PAR.TXT
ECHO ASSIGN LETTER=W >> UEFI_PAR.TXT
REM *****************************************************************
REM DATA 파티션을 생성하고 포맷 후 Y:드라이브로 만든다.
REM *****************************************************************
IF %PAR_D_DRIVE_SIZE% == 0 (
ECHO CREATE PARTITION PRIMARY >> UEFI_PAR.TXT
) ELSE (
ECHO CREATE PARTITION PRIMARY SIZE=%PAR_D_DRIVE_SIZE% >> UEFI_PAR.TXT
)
ECHO FORMAT FS=NTFS QUICK LABEL=DATA >> UEFI_PAR.TXT
ECHO ASSIGN LETTER=Y >> UEFI_PAR.TXT
REM *****************************************************************
REM DATA의 사이즈가 0보다 크면 RECOVERY 파티션을 생성한다.
REM *****************************************************************
IF %PAR_D_DRIVE_SIZE% GTR 0 (
ECHO CREATE PARTITION PRIMARY >> UEFI_PAR.TXT
ECHO FORMAT FS=NTFS QUICK LABEL=RECOVERY >> UEFI_PAR.TXT
ECHO ASSIGN LETTER=R >> UEFI_PAR.TXT
)
REM *****************************************************************
REM 아래 명령은 EFI파티션(S:)에 BCD를 설치한다.
REM BCDBOOT C:\WINDOWS /S S: /L KO-KR /F ALL
REM *****************************************************************
DISKPART /S UEFI_PAR.TXT > UEFI_PAR.LOG
DEL /Q /F UEFI_PAR.TXT
2. Windows PE로 부팅하여 WinNTSetup으로 아래와 같이 설치한다.
